autodesk inventor takes ages to load

[RabbieBurns]

got the gc suite kitted out with autodesk inventor over the summer, but the teacher is complaining it takes ages to open the program for the student users (up to 20 mins she says?).

 

When we run it as staff it opens in seconds. Is there something silly Ive missed thats causing this? Is it a known problem?

 

They are xp pro workstations

[RabbieBurns]

still having this problem.. anyone got any ideas ?

[tosh74]

Do your students have man profiles ? If so I would look for path/permission problems. If these paths do not exist then Inventor launches a repair process. This can take a while if you have 20+ machines accessing the admin image over the network.

[RabbieBurns]

inventor is installed locally on all the machines and we just have local profiles

[tosh74]

Rab

have u tried actually seeing what happens when a student logs on and runs the software for the first time?

I would setup a teststudent account and logon to one of the machines and run Inventor to try and see what happens.

 

Sorry it's not a definitive answer

[Oops_my_bad]

Rab

have u tried actually seeing what happens when a student logs on and runs the software for the first time?

I would setup a teststudent account and logon to one of the machines and run Inventor to try and see what happens.

 

Sorry it's not a definitive answer

 

Yeh - we all know teachers tend to talk carp, it's probably taking one or 2 minutes but this program is quite heavy. We use it on quite high end machines and it can still take anything upto 2 minutes to load (using local profiles) YESH I KNOWS 2 MINUTES OMG

[RabbieBurns]

I will go and try it myself later. I know she did say that the computer I had to reformat recently works fine, so Im just wondering if they just need a good spring clean.

[SFScotland]

The School that I support had a similar issue (with Inventor 2009 ) and here's what I have found & my workaround:

 

Issue:

 

The first time Inventor is run for an account it attempts to do some diagnostics of the system prior to running. On our system this tended to show as Sophos virus warnings despite Sohos being set to ignore the folders and files associated with Inventor. The PC's were taking 20 minutes (or more) to start inventor. After this had happened the user was able to start Inventor within a few minutes.

 

If the user moved to a Machine they had not already done this procedure on the same would happen.

 

Resolution:

 

Using a test PC (same hardware and software as the Class PCs you are having the issue)

 

1/ Create a new local administrator account

2/ log in with this account and start inventor untill it fully opens.

3/ log out and back in to ensure all configuration has been completed.

4/ Log in with your support account and demote the account created in step 1 to a normal user.

5/ Make a copy of the default user profile (so that you can roll back if any issues)

6/ Copy the profile of the user created in step 1 over the default user profile.

 

At this point you should be able to test using a pupil account and you will find that Inventor starts quickly, but throws up errors saying that it can not access the 'my documents' path of the user created in step 1.

 

This is because Inventor does not use System variables in it's paths (such as %uUSERNAME% or %WINDIR%) and you can not change the paths to use System variables as Inventor can not resolve them to the correct paths.

 

The workaround I used is to utilise a script to change the reuired registry keys. Personally I use a VBScipt hidden beingd a .wsh front end. The users can click on this and it reads the users account name from the system and sets the required registry keys.

 

The script can either be put in a networks share for the users to run, or set to run on logon, depending on your preference and capabilities of the users.

 

 

Details of the VBScript :

 

Dim WshShell, bKey

Dim oNet, sUser, cInitial, startTime

Dim reg1, key1, oExec

 

'get the Os Shell

Set WshShell = WScript.CreateObject("WScript.Shell")

 

 

' Helper object

'get the network object

Set oNet = CreateObject("WScript.Network")

' Get the user name. The use may not be logged

' on when the script starts running; keep checking every 1/2 a

' second until they are logged on.

sUser = oNet.UserName

startTime = Now

Do While sUser = ""

If DateDiff("s", startTime, Now) > 30 Then Wscript.Quit

Wscript.Sleep 500

sUser = oNet.UserName

Loop

 

'sUser now contains the logon account name !!

 

 

' Set the username in Inventor

 

WshShell.RegWrite "HKCU\Software\Autodesk\Inventor\RegistryVersion13.0\System\Preferences\File\UserName", sUser, "REG_SZ"

 

 

' Set the path to Inventor Content Centre

'have to use REG Add command line as VBScript can't deal with the key value (gets confused by the slashes in the value)

 

reg1="HKCU\Software\Autodesk\Inventor\RegistryVersion13.0\System\Preferences\File"

reg2="C:\Program Files\Autodesk\Inventor 2009\Inventor 2009\Bin\Inventor.exe:ContentCenterDir"

key1="C:\Documents and Settings\" & sUser & "\My Documents\Inventor\Content Center Files\R2009"

 

Set oExec = WshShell.Exec("reg add " & reg1 & " /V " & chr(34) & reg2 & chr(34) & " /d " & chr(34) & key1 & chr(34) & " /f" )

 

Do While oExec.Status = 0

WScript.Sleep 100

Loop

 

 

' Set the temp folder

'have to use REG Add command line as VBScript can't deal with the key value (gets confused by the slashes in the value)

 

reg1="HKCU\Software\Autodesk\Inventor\RegistryVersion13.0\System\Preferences\Transactions"

reg2="C:\Program Files\Autodesk\Inventor 2009\Inventor 2009\Bin\Inventor.exe:ScratchDir"

key1="C:\Documents and Settings\" & sUser & "\Local Settings\Temp\\"

 

Set oExec = WshShell.Exec("reg add " & reg1 & " /V " & chr(34) & reg2 & chr(34) & " /d " & chr(34) & key1 & chr(34) & " /f" )

 

Do While oExec.Status = 0

WScript.Sleep 100

Loop

 

 

 

 

' Set the temp folder

'have to use REG Add command line as VBScript can't deal with the key value (gets confused by the slashes in the value)

' This key uses the old 8 character length file/directory names

 

'get the length of sUser

If ( len(sUser) > 8 ) Then

'if longer than 8, find first 6 characters and add ~1

sUserShort = Left(sUser, 6) & "~1"

Else

' don't change

sUserShort = sUser

End If

 

 

reg1="HKCU\Software\Autodesk\Inventor\RegistryVersion13.0\System\Preferences\Transcript"

reg2="C:\Program Files\Autodesk\Inventor 2009\Inventor 2009\Bin\Inventor.exe:TransDir"

key1="C:\DOCUME~1\" & sUserShort & "\LOCALS~1\Temp\\"

 

Set oExec = WshShell.Exec("reg add " & reg1 & " /V " & chr(34) & reg2 & chr(34) & " /d " & chr(34) & key1 & chr(34) & " /f" )

 

Do While oExec.Status = 0

WScript.Sleep 100

Loop

 

BtnCode = WshShell.Popup("Inventor Fix has been applied to this PC for user : " & sUser,30 , "Inventor 2009 Fix", 0 + 16)