Installing SIMS and Solus via SCCM - How I do it.

[mdrabble]

Original thanks should go to @rrafluap and his post http://www.edugeek.net/forums/mis-systems/189512-sims-solus3-re-imaging-workstation.html#post1620875

 

I basically took his scripts and changed to suit.

 

You will need to change the following:

 

SCCMSERVER to your SCCM/MDT Sever Name

SOURCES$ to your Deployment Share

 

You get the general idea.....

 

SIMS.net Details

 

1.Create a deployment folder (I called mine SIMSInstaller) and create the following files.

 

SIMSInstaller.bat with the following

wscript.exe "\\SCCMSERVER\SOURCES$\SOFTWARE\SIMSInstaller\SimsInstaller.vbs"
[/Code]

 
[b]SIMSInstaller.vbs[/b] with the following
[code]
strFolder = Replace(WScript.ScriptFullName,WScript.ScriptName,"")

Set WSHShell = CreateObject("WScript.Shell") 
Set WSHNetwork = WScript.CreateObject("WScript.Network")

strComputerName = WSHNetwork.ComputerName

WSHShell.run "xcopy """ & strFolder & "SIMS.ini"" ""C:\Windows"" /y", 1, True
WSHShell.run strFolder & "SIMS\SIMSInfrastructureSetup.exe /S {QuietMode} {SIMSWorkstation}", 1, True
WSHShell.run strFolder & "SIMS\SIMSManualSetup.exe /S {QuietMode} [sIMSDirectory]=""\\SIMS_SERVER\SIMS_SHARE$\SIMS\"" [sIMSDotNetDirectory]=""C:\Program Files\SIMS\SIMS .net""", 1, True
WSHShell.run strFolder & "SIMS\SIMSAMPARKSetup.exe /S {QuietMode} [sIMSDirectory]=""\\SIMS_SERVER\SIMS_SHARE$\SIMS\"" [sIMSDotNetDirectory]=""C:\Program Files\SIMS\SIMS .net""", 1, True
WSHShell.run strFolder & "SIMS\SIMSApplicationSetup.exe /S {QuietMode} [sIMSDirectory]=""\\SIMS_SERVER\SIMS_SHARE$\SIMS\"" [sIMSDotNetDirectory]=""C:\Program Files\SIMS\SIMS .net""", 1, True
WSHShell.run "xcopy """ & strFolder & "connect.ini"" ""C:\Program Files\SIMS\Sims .net"" /y", 1, True

WScript.quit()

 

3. Create a folder called SIMS inside the deployment folder containing the .bat and .vbs files - and copy the following into it:

• SIMSInfrastructureSetup.EXE

• SIMSApplicationSetup.exe

• SIMSAMPARKSetup.exe

• SIMSManualSetup.exe

 

I also copied over the .signature files for good measure.

 

4. Copy your Connect.ini and SIMS.ini and place them in same location as the .bat and .vbs files.

 

5. Create an SCCM Package which contains Source Files and runs the SIMSInstaller.bat

 

 

SOLUS 3 Details

 

1.Create a deployment folder (I called mine SOLUSInstaller) and create the following files.

 

SOLUSInstaller.bat with the following

wscript.exe "\\SCCMSERVER\SOURCES$\SOFTWARE\SOLUSInstaller\SOLUSInstaller.vbs"
[/Code]

 
[b]SOLUSInstaller.vbs[/b] with the following
[code]
strFolder = Replace(WScript.ScriptFullName,WScript.ScriptName,"")

Set WSHShell = CreateObject("WScript.Shell") 
Set WSHNetwork = WScript.CreateObject("WScript.Network")
Set WSHFSO = CreateObject("Scripting.FileSystemObject")

strTempDir = WSHShell.ExpandEnvironmentStrings("%temp%")
strInstallTemp = strTempDir & "\SOLUS3Temp"

strCompName = WSHNetwork.ComputerName
strLogDir = "C:\Windows\Temp"

Set TypeLib = CreateObject("Scriptlet.TypeLib")
strGUID = TypeLib.Guid
strGUID = Left(strGUID, 38)

If NOT WSHFSO.FolderExists(strInstallTemp) Then
WSHFSO.CreateFolder(strInstallTemp)
End If

WSHFSO.CopyFolder strFolder & "\SolusAgent", strInstallTemp, True 

WSHShell.Run "taskkill /f /im Sims.Solus3.Agent.UI.exe", 0, True
WSHShell.Run "net stop Solus3Agent", 0, True

WSHShell.Run "msiexec.exe /lv* """ & strLogDir & "\" & strCompName & "_SOLUS3_Installer.log"" /i """ & strInstallTemp & "\SOLUS3AgentInstaller_x64.msi"" AGENTSERVICEADDRESS=""net.tcp://localhost:52966"" AGENTID=""" & strGUID & """ DEPLOYMENTSERVERADDRESS=""net.tcp://CHANGE_TO_YOUR_SIMS_SERVER_NAME:52965"" RSAKEYPATH=""" & strInstallTemp & """ MSIRESTARTMANAGERCONTROL=0 /norestart /qb!", 1, True

WSHShell.Run "net start Solus3Agent", 0, True

WSHFSO.DeleteFolder(strInstallTemp)

WScript.Quit

 

(As I only use 64 Bit, I only referenced and copied over the x64 installer)

 

3. Create a folder called SolusAgent inside the deployment folder and copy the SolusAgent files from your SIMS Server

 

• Solus3AgentInstaller_x64.msi

• Solus3.Keys.DeploymentService.Public.xml

 

 

4. Create an SCCM Package which contains Source Files and runs the SOLUSInstaller.bat

 

 

Now some may be thinking what about updating the SIMS.net and Solus Packages when new versions appear.

 

I have Solus set to deploy updates Automatically, so the Solus Agent will automatically update. - I did test with an older V3 Solus Agent and when installed, it doesnt detect SIMS is installed even though it is. - Once Solus has Automatically updated, it then detects SIMS.net and will automatically update SIMS.net if the deployed version is older.

 

I only deploy these files as part of the Task Sequence on the Initial OS Deployment - I do not have them set to deploy to collections etc.

 

I have tested by rebullding stations from scratch wiith new computer name and by using the the original computer name - I havent had to touch Solus during the deployment process.

 

 

Hope people find this useful and as mentioned thanks to @rrafluap

Edited May 17, 2019 by mdrabble

[mavhc]

You don't use the AgentInstaller.js?

[mdrabble]

Could never get the AgentInstaller.js to install correctly for some strange reason when using SCCM but would work absolutely fine if ran manually

[mavhc]

Odd, I run it from a bat file via GPO

[nicholab]

Hi I seem to be getting an out of data version of SIMS is there a way to install the current versions? I also seem to have had SIMS install in the C:\Program Files rather then the C:\Program Files (x86) any ideas?

[mavhc]

Ask for your money back until they learn how to write software?

 

In SOLUS you can specify the install location, it's very easy to end up with 2 copies, and then FMS finds the wrong one or something.

[nicholab]

The SIMS installer script just needs updating to point to C:\Program Files (x86).

[mdrabble]

Strange, works fine here - when I use to deploy via Solus, it always installed to Program Files and not Program Files (x86) which would have imagined it would have - so I kept it pointed to Program Files and had no issues.

[mavhc]

My council support guy says it's recommended to use Program Files, but Solus will default to (x86), and that they're abandoning the whole codebase for a web based system. But FMS won't be translated, so they acqhired a company to write something new

[localzuk]

Hi I seem to be getting an out of data version of SIMS is there a way to install the current versions? I also seem to have had SIMS install in the C:\Program Files rather then the C:\Program Files (x86) any ideas?

This'll be due to using the setups folder to install the client initially - you're not likely to have the latest installers there. Theoretically, SOLUS should update it when it checks in anyway!

[gwendes]

Sorry to drag this thread up again. I've got the batch file working if I run it, but not through SCCM. Any ideas?