[sims] [SOLUS3] Auto Reinstall

[johnhart96]

Hi,

 

We use a workstation management system that can schedule the redeployment of PCs. I do this a lot for out of hours rebuilds.

Does anyone know a way of doing the same thing with SOLUS 3 installs ?

 

John

Edited February 25, 2015 by johnhart96

[Boredguy]

When we deploy out SIMS, we use a VBS script that checks the station name against a CSV file that holds a copy of the workstation name & Solus 3 GUID (since I didn't want to keep looking at the main DB)

 

If the station name exists in the CSV, it passes that GUID into the installer string, otherwise it generates the new GUID and updates the CSV.

 

Depending on your workstation management you might be able to do something similar so that you do not have to keep redefining what SIMS component should be on the station after rebuild.

[johnhart96]

That sounds cool,

If possible, can you upload the script and a blank CSV ?

[Boredguy]

SolusInstall.vbs (32bit version)

3 Variables to update to point to where your Solus3 Agent Installer is, location of the guid file, and the name of your SIMS Server

Const ForReading = 1, ForWriting = 2, ForAppending = 8

Set wshShell = WScript.CreateObject("WScript.Shell")
Set TypeLib = CreateObject("Scriptlet.TypeLib")
Set wshNetwork = WScript.CreateObject( "WScript.Network" )
Set fso = CreateObject("Scripting.FileSystemObject")

Filename = "\\server\share$\SIMS .Net\guids.csv"
InstallLoc = "\\server\share$\SIMS .Net"
SimsServer = "SIMSServerName"

Found = false
strComputer = wshNetwork.ComputerName

Set MyFile = fso.OpenTextFile(FileName, ForReading)
Do While MyFile.AtEndOfStream <> True
temp = MyFile.Readline
if instr(temp,strComputer) > 0 then 
	GUID = Left(temp,instr(temp,",")-1)
	found = true
End if
Loop
MyFile.Close

If found = false then 
GUID = left(TypeLib.Guid,37)
GUID = Right(Guid,36)
Set MyFile = fso.OpenTextFile(FileName, ForAppending, True, TristateTrue)
MyFile.WriteLine GUID & "," & strComputer
MyFile.Close	

end if
wshShell.Run "msiexec.exe /i " & chr(34) & InstallLoc & "\SOLUS3AgentInstaller_x86.msi" & chr(34) & " AGENTSERVICEADDRESS=" & chr(34) & "net.tcp://localhost:52966" & chr(34) & " AGENTID=" & chr(34) & "{" & GUID & "}" & chr(34) & " DEPLOYMENTSERVERADDRESS=" & chr(34) & "net.tcp://" & SimsServer & ":52965" & chr(34) & " RSAKEYPATH=" & chr(34) & InstallLoc  & chr(34) & " /qn", 1, true

 

Guid.csv

You can export your current GUID list from the Solus3 Database. Table is solus3.agent

XXXXXXXX-XXXX-XXXXX-XXXX-XXXXXXXXXXXX,Station1.site.internal