I don't think you can do this from the GUI, but you should be able to with a bit of scripting. e.g. using vbscript and the NETSH command:
I have not fully tested this, so as always make a backup before using it.
' script to bulk create DHCP reservations from a .csv file
' Set a couple of constants
' Set following line to IP address of DHCP server, or leave blank for local computer
Const DHCPServer = ""
' Set following line to address scope where reservation is to be added
Const SCOPE = "192.168.1.0"
' Set following line to location of .csv file containing the reservation to be added
Const FileLocation = "C:\reservations.csv"
' read in the csv file
' <Reserved IP>,<MAC>,<Client Name>,<Description>
Const forReading = 1
Set objShell = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objCSVFile = objFSO.OpenTextFile(FileLocation,forReading)
' Process csv file
Do While objCSVFile.AtEndOfStream <> True
' read in a line from the csv file
strLine = objCSVFile.ReadLine
' seperate the cells on the line
arrCells = split(strLine,",",-1,1)
' get the values from the cells
strIP = arrCells(0)
strMAC = arrCells(1)
strClientName = arrCells(2)
strDescription = arrCells(3)
' build the NETSH command string
strCmd = "netsh dhcp server " & DHCPServer & " scope " & SCOPE & " add reservedip " & _
strIP & " " & strMAC & " " & strClientName & " """ & strDescription & """"
' run the NETSH command
objShell.Run strCmd, 1, TRUE
' All done so close the csv file
' Clean up objects
Set objCSVFile = Nothing
Set objFSO = Nothing
Set objShell = Nothing
WScript.Echo "All done."
Hope that is of some help,