Windows 7 for students

[zag]

We've had Windows 7 for a long time for staff but I never bothered moving the students over to it. So I have a few questions before deployment.

- Is there a group policy for getting the old login box back (at the moment it just asks for the previous users password)

- How do I set-up a mandatory profile in Windows 7? (Just put the .v2 file in the profile share?)

- Is there any way to disable students clicking on the wireless connection and disconnecting from the wireless network?

- How do I disable students browsing the "homegroup" or "entire network"

- How do I make Google the default search provider on IE9?

Cheers

[FN-GM]

- you can set it so it asks for a username and password for every login. Jut set it the same was as windows xp
- yep
- yep here is a group policy under taskbar I think
- there are group policy templates you can download and add to your policy I don't have a link handy right now.
- not sure I would like to know myself :-)

[zag]

Thanks, but how do I make the profile mandatory in windows 7?

I have studentprofile.V2 all done but there is no file to rename .man like windows xp

[zag]

Is there any way to disable students clicking on the wireless connection and disconnecting from the wireless network?

[fixed] UC >> Admin tools >> Start menu and task bar >> Hide the notification area

[zag]

- Is there a group policy for getting the old login box back (at the moment it just asks for the previous users password)

[fixed] CC >> windows settings >> security settings >> local policies >> security options >> Interactive login:do not display last username

[fixed] CC >> windows settings >> security settings >> local policies >> security options >> Interactive login:do not require ctrl + alt + delete

[FN-GM]

Is there any way to disable students clicking on the wireless connection and disconnecting from the wireless network?

[fixed] UC >> Admin tools >> Start menu and task bar >> Hide the notification area

This is not correct that will hide all icons. This is a better one just to remvoe the network one only.

User Configurartion > Administrative Templates > Start Menu & Task Bar > Remove the networking icon.

[FN-GM]

Thanks, but how do I make the profile mandatory in windows 7?

I have studentprofile.V2 all done but there is no file to rename .man like windows xp

There should be. You may hasve to turn on view system files in the folder options to see it.

[zag]

Getting there....

I'm trying to move away from server profiles all together. First of all is this a good idea?

We are running on SSD clients here site wide now and logons take less than 8 seconds without a roaming or mandatory profile. I.E. Profile field left blank in AD user.

Second how to I prevent office 2010 always asking the persons name on first login? That seems to be the only niggle.

[FN-GM]

I have a little script that you can run on login that will populate the office details. When i get home i will post it. If i dont i would have forgot so give me a nudge

If you have quick logon times like that you might as well as use local profiles.

[FN-GM]

Here we go. This VBS script is to be run as a logon script. It will setup the user name for office pulling the details from AD. But it think its office 2003 and 2007 not 2010 i will see if i can adapt it. it might work though.

Thanks

' Reads from AD Display Name and initials from First name and Last name.
' Writes this info into the registry for the Office username and initials.

Option Explicit

Const HKCU = &H80000001
Const HKLM = &H80000002

Dim oADSystemInfo, oADsUser, oReg
Dim sDisplayName, sInitials, sOfficeVersion, sRegKey, sPath
Dim aUsername, aInitials, aOfficeVersions
Dim iRC1, iRC2, iRet

aOfficeVersions = Array("12.0","11.0","10.0","9.0","8.0")

On Error Resume Next

' Get full username from AD
Set oADSystemInfo = CreateObject("ADSystemInfo")

' get AD user object
Set oADsUser = GetObject("LDAP://" & oADSystemInfo.UserName)

' get full name of the current user and the account name
sDisplayName = oADsUser.givenName & " " & oADsUser.SN
'sDisplayName = oADsUser.DisplayName
' Removed, JP, 24/08.06 & " (" & oADsUser.SAMAccountName & ")"


' get initials of the current user
sInitials = Left(oADsUser.givenName, 1) & Left(oADsUser.SN, 1)

' Create a byte array of the name and initials 
aUsername = ToByteArray(sDisplayName)
aInitials = ToByteArray(sInitials)
' Quit if there was an error converting to a byte array
If UBound(aUsername) = -1 Or UBound(aInitials) = -1 Then WScript.Quit

' Connect to the registry (via WMI)
Set oReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" _
      & ".\root\default:StdRegProv")

' quit if any errors have occurred
If Err <> 0 Then WScript.Quit


' find the Office version(s) installed
For Each sOfficeVersion In aOfficeVersions

	sRegKey = "SOFTWARE\Microsoft\Office\" & sOfficeVersion _
      & "\Common\InstallRoot"

	iRet = oReg.GetStringValue (HKLM, sRegKey, "Path", sPath)

	If iRet <> 0 Or sPath = "" Then
		'WScript.Echo "Checking 64-bit path"
		sRegKey = "SOFTWARE\Wow6432Node\Microsoft\Office\" & sOfficeVersion _
			& "\Common\InstallRoot"   
		iRet = oReg.GetStringValue (HKLM, sRegKey, "Path", sPath)
	End If
	
   
	If sPath <> "" Then
		'WScript.Echo "Updating userinfo"
		' Found an installed Office version, now update UserName value in HKCU

		If CSng(sOfficeVersion) >= 12.0 Then
			sRegKey = "SOFTWARE\Microsoft\Office\Common\UserInfo"
			
			' create the key if it doesn't exist
			oReg.CreateKey HKCU, sRegKey

			' set the UserName and Initials values using string values
			iRC1 = oReg.SetStringValue(HKCU, sRegKey, "UserName", sDisplayName)
			iRC2 = oReg.SetStringValue(HKCU, sRegKey, "UserInitials", sInitials)
		
		Else
			
			sRegKey = "SOFTWARE\Microsoft\Office\" & sOfficeVersion & "\Common\UserInfo"
			
			' create the key if it doesn't exist
			oReg.CreateKey HKCU, sRegKey

			' set the UserName and Initials values using binary values
			iRC1 = oReg.SetBinaryValue(HKCU, sRegKey, "UserName", aUsername)
			iRC2 = oReg.SetBinaryValue(HKCU, sRegKey, "UserInitials", aInitials)
		End If

	End If
Next


' returns an empty array for error (the length of an empty array is -1)
Function ToByteArray(ByVal sString)
   Dim iIndex, iPos

   ' return an empty array if a sString is not a string
   If VarType(sString) <> vbString Then 
      ToByteArray = Array()
      Exit Function
   End If

   ReDim aBytes(Len(sString) * 2 + 1)

   iIndex = -1
   For iPos = 1 To Len(sString)
     iIndex = iIndex + 1
     aBytes(iIndex) = Asc(Mid(sString, iPos, 1))
     ' add a 0 after each letter
     iIndex = iIndex + 1
     aBytes(iIndex) = 0
   Next

   ' add two closing 0's
   iIndex = iIndex + 1
   aBytes(iIndex) = 0
   iIndex = iIndex + 1
   aBytes(iIndex) = 0

   ToByteArray = aBytes
End Function

[zag]

Brilliant stuff.

Here is the Office 2010 Reg key, maybe its simpler now?

Disabling "Please enter your full name and initials below"

[zag]

Anyone know how to disable Powershell for students?

I ran a little "hackathon" with a few ict prefects today and they found a way to access powershell from the search box on the start menu. Clever kids!!

[cromertech]

Second how to I prevent office 2010 always asking the persons name on first login? That seems to be the only niggle.

I redirected the appdata. This prevented it asking everytime. It does still ask on first log in. This gave another problem though with a security error when launching from the task bar but adding the unc to the appdata folder to trusted sites sorted that one out.

[enjay]

We moved to Windows 7 for everyone in the summer - our setup isn't perfect by any measure, but you're welcome to come have a look if you want.

[FN-GM]

Anyone know how to disable Powershell for students?

I ran a little "hackathon" with a few ict prefects today and they found a way to access powershell from the search box on the start menu. Clever kids!!

Its actually disabled by default and you need to be an admin to enable it