+ Post New Thread
Results 1 to 15 of 15
Scripts Thread, Script not setting the correct default printer in Coding and Web Development; Guys and Gals, I have a scripty that maps printers based on Computer OU or User Group, but the User ...
  1. #1

    Join Date
    Aug 2009
    Posts
    76
    Thank Post
    2
    Thanked 9 Times in 5 Posts
    Rep Power
    11

    Script not setting the correct default printer

    Guys and Gals,

    I have a scripty that maps printers based on Computer OU or User Group, but the User group Mapping isnt working, it just makes the first in the If list the default, can someone have a look over as im not a scrip genius and just cut and shut scripts together.

    As i say the OU bit works great but cannot get the Bt group bit to default a printer based on Groups called year 1, Year 2 etc

    Thanks

    Code:
    'Variables
    
    Set objSysInfo = CreateObject("ADSystemInfo")
    strName = objSysInfo.ComputerName
    arrComputerName = Split(strName, ",")
    arrOU = Split(arrComputerName(1), "=")
    strComputerOU = arrOU(1)
    Set objNetwork = CreateObject("WScript.Network")
    Set objPrinters = objNetwork.EnumPrinterConnections
    strUser = objNetwork.UserName
    strDomain = SPRINGGROVE
    
    'Remove all the Network Printers from the Machine
    
    For i = 0 to objPrinters.Count - 1 Step 2
     
                On Error Resume Next
     
         if Left(objPrinters.Item(i), 3) <> "lpt" And Left(objPrinters.Item(i), 3) <> "usb" then
     
                  objNetwork.RemovePrinterConnection objPrinters.Item(i+1), true, true
     
                else Echo "No network printers found"
     
                end if
     
    Next
    
    'Map Global Printers
    
    objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\CopierColour"
    objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\CopierMono"
    objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\ICTSuite"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb01\Year1"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb02\Year2"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb03\Year3"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb04\Year4"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb05\Year5"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb06\Year6"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb07\EYUClass"
    objNetwork.AddWindowsPrinterConnection "\\Spring-eyu02\EYUPlay"
    
     
    'Map Printers Based on Group (Use Actual Printer name for local Printers) (Move below OU Section if you want to apply group defaults after)
    
    Set objGroups = GetObject("WinNT://"& strDomain & "/" & strUser & ",user")
    For Each objGroups In objGroups.Groups
    
    If objGroups.Name = "Year 1" Then
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb01\Year1"
    objNetwork.SetDefaultPrinter "\\Spring-iwb01\Year1"
    
    ElseIf objGroups.Name = "Year 2" Then
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb02\Year2"
    objNetwork.SetDefaultPrinter "\\Spring-iwb02\Year2"
    
    ElseIf objGroups.Name = "Year 3" Then
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb03\Year3"
    objNetwork.SetDefaultPrinter "\\Spring-iwb03\Year3"
    
    ElseIf objGroups.Name = "Year 4" Then
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb04\Year4"
    objNetwork.SetDefaultPrinter "\\Spring-iwb04\Year4"
    
    ElseIf objGroups.Name = "Year 5" Then
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb05\Year5"
    objNetwork.SetDefaultPrinter "\\Spring-iwb05\Year5"
    
    ElseIf objGroups.Name = "Year 6" Then
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb06\Year6"
    objNetwork.SetDefaultPrinter "\\Spring-iwb06\Year6"
    
    
    End If
    
    Next
     
    'Map Printers based on OU (Use Actual Printer name for local Printers) 
    
    Select Case strComputerOU
        Case "EYU Class"
            objNetwork.AddWindowsPrinterConnection "EYU Class"
            objNetwork.SetDefaultPrinter "EYU Class"
            objNetwork.SetDefaultPrinter "\\Spring-iwb07\EYUClass"
        Case "EYU Play"
            objNetwork.AddWindowsPrinterConnection "EYU Play"
            objNetwork.SetDefaultPrinter "EYU Play"
            objNetwork.SetDefaultPrinter "\\Spring-eyu02\EYUPlay"
        Case "ICT Suite"
            objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\ICTSuite"
            objNetwork.SetDefaultPrinter "\\Spring-svr01\ICTSuite"
        Case "Library"
            objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\ICTSuite"
            objNetwork.SetDefaultPrinter "\\Spring-svr01\ICTSuite"
    
    End Select

  2. #2
    cromertech's Avatar
    Join Date
    Dec 2007
    Location
    Cromer by the coast
    Posts
    731
    Thank Post
    177
    Thanked 109 Times in 97 Posts
    Rep Power
    54
    You can try to use case statements for the year groups so instead of

    Code:
    If objGroups.Name = "Year 1" Then
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb01\Year1"
    objNetwork.SetDefaultPrinter "\\Spring-iwb01\Year1"
    
    ElseIf objGroups.Name = "Year 2" Then
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb02\Year2"
    objNetwork.SetDefaultPrinter "\\Spring-iwb02\Year2"
    etc it would read
    Code:
    Select Case objGroups.Name 
    Case "Year 1"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb01\Year1"
    objNetwork.SetDefaultPrinter "\\Spring-iwb01\Year1"
    
    Case "Year 2"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb02\Year2"
    objNetwork.SetDefaultPrinter "\\Spring-iwb02\Year2"

  3. #3

    Join Date
    Aug 2009
    Posts
    76
    Thank Post
    2
    Thanked 9 Times in 5 Posts
    Rep Power
    11
    Tried that it doesnt work, it doesnt give and error but doesnt select the correct default (like its not picking up what group the user is in)

    Heres what i ammended it to:

    Code:
    'Variables
    
    Set objSysInfo = CreateObject("ADSystemInfo")
    strName = objSysInfo.ComputerName
    arrComputerName = Split(strName, ",")
    arrOU = Split(arrComputerName(1), "=")
    strComputerOU = arrOU(1)
    Set objNetwork = CreateObject("WScript.Network")
    Set objPrinters = objNetwork.EnumPrinterConnections
    strUser = objNetwork.UserName
    strDomain = SPRINGGROVE
    
    'Remove all the Network Printers from the Machine
    
    For i = 0 to objPrinters.Count - 1 Step 2
     
                On Error Resume Next
     
         if Left(objPrinters.Item(i), 3) <> "lpt" And Left(objPrinters.Item(i), 3) <> "usb" then
     
                  objNetwork.RemovePrinterConnection objPrinters.Item(i+1), true, true
     
                else Echo "No network printers found"
     
                end if
     
    Next
    
    'Map Global Printers
    
    objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\CopierColour"
    objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\CopierMono"
    objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\ICTSuite"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb01\Year1"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb02\Year2"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb03\Year3"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb04\Year4"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb05\Year5"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb06\Year6"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb07\EYUClass"
    objNetwork.AddWindowsPrinterConnection "\\Spring-eyu02\EYUPlay"
    
     
    'Map Printers Based on Group (Use Actual Printer name for local Printers) (Move below OU Section if you want to 
    
    apply group defaults after)
    
    Set objGroups = GetObject("WinNT://"& strDomain & "/" & strUser & ",user")
    For Each objGroups In objGroups.Groups
    
    Select Case objGroups.Name 
    
    Case "Year 1"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb01\Year1"
    objNetwork.SetDefaultPrinter "\\Spring-iwb01\Year1"
    
    Case "Year 2"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb02\Year2"
    objNetwork.SetDefaultPrinter "\\Spring-iwb02\Year2"
    
    Case "Year 3"
    objNetwork.AddWindowsPrinterConnection "\\Spring-iwb03\Year3"
    objNetwork.SetDefaultPrinter "\\Spring-iwb03\Year3"
    
    
    End Select
    
    Next
     
    'Map Printers based on OU (Use Actual Printer name for local Printers) 
    
    Select Case strComputerOU
        Case "EYU Class"
            objNetwork.AddWindowsPrinterConnection "EYU Class"
            objNetwork.SetDefaultPrinter "EYU Class"
            objNetwork.SetDefaultPrinter "\\Spring-iwb07\EYUClass"
        Case "EYU Play"
            objNetwork.AddWindowsPrinterConnection "EYU Play"
            objNetwork.SetDefaultPrinter "EYU Play"
            objNetwork.SetDefaultPrinter "\\Spring-eyu02\EYUPlay"
        Case "ICT Suite"
            objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\ICTSuite"
            objNetwork.SetDefaultPrinter "\\Spring-svr01\ICTSuite"
        Case "Library"
            objNetwork.AddWindowsPrinterConnection "\\Spring-svr01\ICTSuite"
            objNetwork.SetDefaultPrinter "\\Spring-svr01\ICTSuite"
    
    End Select

  4. #4
    ajs
    ajs is offline

    Join Date
    Jun 2008
    Location
    Wigton, Cumbria
    Posts
    226
    Thank Post
    2
    Thanked 35 Times in 35 Posts
    Rep Power
    23
    Quote Originally Posted by Scorpio View Post

    strDomain = SPRINGGROVE
    I'd put "" around SPRINGROVE as (unless I'm completely off with my understanding of the code) your script will look for another variable called SPRINGGROVE and will try and use whatever value that variable has. Since there isn't a variable with that name your strDomain will end up being empty.

    I may be making this up but I think that when using the WinNT method all the properties of an object are returned in uppercase so you want to change your code to use uppercase values in your case statement. So:


    Select Case objGroups.Name

    Case "Year 1"
    would become

    Select Case objGroups.Name

    Case "YEAR 1"
    If that still doesn't work then you can comment out the "On Error Resume Next" (using a ' at the start if you didn't know) line and the script will show any error messages that occur when it is run (along with codes and line numbers to help you track down the error)

  5. #5

    Join Date
    Aug 2009
    Posts
    76
    Thank Post
    2
    Thanked 9 Times in 5 Posts
    Rep Power
    11
    The quotes around the domain name worked, thanks

    Also had to create a bit more on the script to delete a reg entry as there was a ghost printer that this script wouldnt get rid of.

    Thanks again

    PS didnt need to do the CAPS on the Year 1 etc

  6. #6
    eean's Avatar
    Join Date
    May 2006
    Location
    Kuala Lumpur
    Posts
    559
    Thank Post
    65
    Thanked 52 Times in 37 Posts
    Rep Power
    29
    Here's my default printer script - may be useful for someone. It works in a slightly different way. It might be slightly faster because the printer connections are per machine so don't need to be recreated on each logon. Also, it keeps the default printer information all in Group Policy, which makes it easier for editing especially when working with less script-savvy techs.
    I have also used the method described by the original poster and it does work well.

    First of all, you install the printer to the local machine using the pushprinterconnections method in Group Policy See here. This makes the printer available to all users on the machine but it doesn't set it as default. As we know, the problem with windows is the default printer option is controlled by the user part of the registry, not the computer. (Daft!).

    You use a custom ADM file (attached) in Group policy - this writes a the name of the default printer to the local machine in the registry. You can use either the network or local name e.g. "\\svr1\printer" or "Canon 123") We now have a default printer value for the computer, rather than the user.

    This script runs is called by the logon script (or could be called through GP). It reads the registry value, looks up the port name of the printer, then sets the default printer. It adds a registry key to set the default printer rather than using the WSH SetDefaultPrinter command. The reason is that the printer doesn't actually appear until a few minutes after logon so the SetDefaultPrinter method fails.

    The script has a few extra If's than needed. This was because I was planning on making it more clever e.g. adding per user option. Or making it so it would set a local printer if there was one attached. It could also do with some error checking - e.g. what do do if the printer that is supposed to be default isn't actually installed.


    Code:
    'Option Explicit
    
    Dim WShell, PrinterPol
    
    Set objShell = WScript.CreateObject("WScript.Shell")
    
    
    
    '****Read the value for the default printer set by group policy
    
    'Switch Error Reporting Off
    
    On Error Resume Next
    
    'Attempt to read key (This key has been written by Group Policy via the custom ADM file)
    strPrinterPol = objShell.RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\DefaultPrinter\DefaultPrinter")
    
    'Turn error reporting back on
    On Error Goto 0
    
    'Check the length of the key to see if the registry has retrieved anything.
    If Len(strPrinterPol) > 0 Then
    	Call funSetDefaultPrinter(strPrinterPol)
    
    Else
    '	Wscript.echo "policy doesn't exist"
    
    End If
    
    
    Wscript.Quit
    
    '##########   Functions   ############
    
    
    Function funSetDefaultPrinter(strPrinterName)
    
    'Get details about the printer, e.g. what it uses to spool (e.g. winspool) and port name (e.g NE01:)
    'These commands just read from the registry but because the path to the key may contain back slashes the normal regread function won't work
    'strPrinterPort is what is returned (it will be like "winspool, NE01:") 
    
    Const HKEY_USERS = &H80000003
    strComputer = "."
    Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
     
    strKeyPath = ".DEFAULT\Software\Microsoft\Windows NT\CurrentVersion\Devices"
    
    objReg.GetStringValue HKEY_USERS, strKeyPath, strPrinterName, strPrinterPort
    
    'wscript.echo StrPrinterPort
    'Put the printer name and port name together
    strDefPrintKey = StrPrinterName & "," & strPrinterPort
    
    
    'Now Write the values to the registry to set the default printer
    objShell.RegWrite "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows\Device", strDefPrintKey, "REG_SZ"
    
    End Function
    Attached Files Attached Files

  7. #7

    Join Date
    Aug 2005
    Location
    London
    Posts
    3,154
    Thank Post
    114
    Thanked 527 Times in 450 Posts
    Blog Entries
    2
    Rep Power
    123
    Quote Originally Posted by ajs View Post
    I may be making this up but I think that when using the WinNT method all the properties of an object are returned in uppercase so you want to change your code to use uppercase values in your case statement.
    Don't think you're making it up but it's not safe to assume that you'll get all caps, all lower case etc.

    What I always do is something like this:
    Code:
    sGroup=ucase(objgroups.name)
    select case sGroup
      case "YEAR 1"
    
    ...
    
    end select
    That way, you're sure that you're working with upper case even if something in the underlying provider changes

  8. #8

    Join Date
    Aug 2009
    Posts
    76
    Thank Post
    2
    Thanked 9 Times in 5 Posts
    Rep Power
    11
    @eean

    that would be cool but we are not on R2 of windows 2003 so pushing printers out is not an option.

  9. #9

    Join Date
    Oct 2009
    Location
    Walpole, MA
    Posts
    3
    Thank Post
    4
    Thanked 0 Times in 0 Posts
    Rep Power
    0

    custom adm file

    Eean,

    I'm new to this forum.
    Your custom adm file looks like just the solution I've been looking for.
    I tried downlading it, with no luck.
    I can get the zip file, but couldn't read the enclosed file.
    It looks like I'm the only one to try looking at it so far. Did it post correctly? Or, could I be doing something wrong (Entirely Likely)

    Thanks!

    Ann

  10. #10
    eean's Avatar
    Join Date
    May 2006
    Location
    Kuala Lumpur
    Posts
    559
    Thank Post
    65
    Thanked 52 Times in 37 Posts
    Rep Power
    29
    Hmm... that's wierd. It's not letting me either.

    Copy and paste this script into Notepad and save it as defaultprinter.vbs

    Code:
    Dim WShell, PrinterPol
    
    Set objShell = WScript.CreateObject("WScript.Shell")
    
    
    
    '****Read the value for the default printer set by group policy
    
    'Switch Error Reporting Off
    
    On Error Resume Next
    
    'Attempt to read key
    strPrinterPol = objShell.RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\DefaultPrinter\DefaultPrinter")
    
    'Turn error reporting back on
    On Error Goto 0
    
    'Check the length of the key to see if the registry has retrieved anything.
    If Len(strPrinterPol) > 0 Then
    	Call funSetDefaultPrinter(strPrinterPol)
    
    Else
    '	Wscript.echo "policy doesn't exist"
    
    End If
    
    
    Wscript.Quit
    
    '##########   Functions   ############
    
    
    Function funSetDefaultPrinter(strPrinterName)
    
    'Get details about the printer, e.g. what it uses to spool (e.g. winspool) and port name (e.g NE01:)
    'These commands just read from the registry but because the path to the key may contain back slashes the normal regread function won't work
    'strPrinterPort is what is returned (it will be like "winspool, NE01:") 
    
    Const HKEY_USERS = &H80000003
    strComputer = "."
    Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
     
    strKeyPath = ".DEFAULT\Software\Microsoft\Windows NT\CurrentVersion\Devices"
    
    objReg.GetStringValue HKEY_USERS, strKeyPath, strPrinterName, strPrinterPort
    
    'wscript.echo StrPrinterPort
    'Put the printer name and port name together
    strDefPrintKey = StrPrinterName & "," & strPrinterPort
    
    
    'Now Write the values to the registry to set the default printer
    objShell.RegWrite "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows\Device", strDefPrintKey, "REG_SZ"
    
    End Function
    Copy and paste this script and save it as defaultprinter.adm
    Code:
    CLASS MACHINE 
    
    CATEGORY "Printers" 
    	POLICY "Set Default Printer" 
    
    		KEYNAME "Software\Microsoft\Windows\CurrentVersion\Policies\DefaultPrinter"
    		PART "DefaultPrinter"
    			EDITTEXT
    			VALUENAME "DefaultPrinter"
    		END PART 
    	END POLICY 
    END CATEGORY
    I'm assuming that you've already got printers installing themselves via group policy and pushprinterconnections.exe utility. And also that you know how to add custom adm files to group policy and add vbs files to your logon batch file (you could probably also initate this script using the logon scripts part of group policy though I haven't tested that). If you need help with these, let me know. It's only been tested with Server 2003 and Windows XP. Good luck!

  11. Thanks to eean from:

    apellowe (26th October 2009)

  12. #11

    Join Date
    Oct 2009
    Location
    Walpole, MA
    Posts
    3
    Thank Post
    4
    Thanked 0 Times in 0 Posts
    Rep Power
    0
    I am definately the less script-savvy tech that you refered to in your post above.

    The lab I'm trying this out in gets the correct printer using group policy and pushprinterconnections.exe.

    I'm running Windows 2003 servers and my labs are all Windows XP machines.

    I was able to get the adm file to work, Thanks!
    HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\pol icies\DefaultPrinter
    gets a string value of DefaultPrinter set to the UNC of the pritner that I want.
    In my case, this is:
    \\highschool\Media Lab - RISO

    The script seems to remove the existing default printer, but not set a new default printer. When I look in Printers and Faxes, none of the printers have the default icon with the checkmark. Although, when I print something, the correct printer does seem to be used.

    So, I'm not sure if I have a problem or not.

    Thanks for the help!

    Ann

  13. #12

    mac_shinobi's Avatar
    Join Date
    Aug 2005
    Posts
    9,680
    Thank Post
    3,210
    Thanked 1,030 Times in 955 Posts
    Rep Power
    361
    Quote Originally Posted by apellowe View Post
    I am definately the less script-savvy tech that you refered to in your post above.

    The lab I'm trying this out in gets the correct printer using group policy and pushprinterconnections.exe.

    I'm running Windows 2003 servers and my labs are all Windows XP machines.

    I was able to get the adm file to work, Thanks!
    HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\pol icies\DefaultPrinter
    gets a string value of DefaultPrinter set to the UNC of the pritner that I want.
    In my case, this is:
    \\highschool\Media Lab - RISO

    The script seems to remove the existing default printer, but not set a new default printer. When I look in Printers and Faxes, none of the printers have the default icon with the checkmark. Although, when I print something, the correct printer does seem to be used.

    So, I'm not sure if I have a problem or not.

    Thanks for the help!

    Ann
    I would use wscripts sleep function / property and make it sleep for about 5 to 10 seconds before trying to set the default printer and the rest of it that way it removes all the printers etc and then sets the defaults etc

    Also error wise may be worth while adding a case else and putting code under there to give you a msgbox or something so you know if there is an error or what happens if none of the above conditions are met ?

  14. Thanks to mac_shinobi from:

    apellowe (29th October 2009)

  15. #13
    ChrisH's Avatar
    Join Date
    Jun 2005
    Location
    East Lancs
    Posts
    4,996
    Thank Post
    120
    Thanked 280 Times in 258 Posts
    Rep Power
    106
    To expand on what is said above it is useful to use message box on all the different conditions so you can see where the code is going.

  16. Thanks to ChrisH from:

    apellowe (29th October 2009)

  17. #14
    eean's Avatar
    Join Date
    May 2006
    Location
    Kuala Lumpur
    Posts
    559
    Thank Post
    65
    Thanked 52 Times in 37 Posts
    Rep Power
    29
    Quote Originally Posted by apellowe View Post

    So, I'm not sure if I have a problem or not.
    Well, if it works then you don't have a problem!
    Try hitting F5 a few times when you go to the printer window. The reason is (and why my script has to set the default printer using the registry rather than the default printer command) is that when when you add printers on a per machine basis (like via pushprinterconnections) it takes a good 30-60seconds before they appear in the printers folder.

    Also check Hkey Current User\Software\Microsoft\Windows NT\CurrentVersion\Windows\ then Device in the registry you should get something like:

    \\highschool\Media Lab - RISO,winspool,Ne04:

    Can you tell me what you get.

    Also, it might not like Media Lab - RISO. Just for testing try making it a one word share name.

  18. Thanks to eean from:

    apellowe (29th October 2009)

  19. #15

    Join Date
    Oct 2009
    Location
    Walpole, MA
    Posts
    3
    Thank Post
    4
    Thanked 0 Times in 0 Posts
    Rep Power
    0

    Got it working, Thanks!

    I took a day off for a conference, and today it is working!!

    Before my day off, Hkey Current User\Software\Microsoft\Windows NT\CurrentVersion\Windows\ was not showing any port information.

    I did add the delay as suggested above, that seemed to help.
    I shortened the name, and redeployed the printer with group policy.

    Between everything, I now get port information and a nice default printer icon with checkmark.

    Thanks All!

SHARE:
+ Post New Thread

Similar Threads

  1. Replies: 13
    Last Post: 20th February 2008, 04:29 PM
  2. setting a default printer for all users
    By wellwillthisnamedothen in forum How do you do....it?
    Replies: 10
    Last Post: 8th June 2007, 03:34 PM
  3. Cunning 'default printer' script
    By ajbritton in forum Scripts
    Replies: 2
    Last Post: 12th November 2006, 09:22 PM
  4. Change network printer default setting
    By speckytecky in forum Wireless Networks
    Replies: 1
    Last Post: 31st May 2006, 06:44 PM
  5. Setting a permanent default printer.
    By ninjabeaver in forum Windows
    Replies: 25
    Last Post: 23rd August 2005, 05:55 PM

Thread Information

Users Browsing this Thread

There are currently 1 users browsing this thread. (0 members and 1 guests)

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •