+ Post New Thread
Results 1 to 4 of 4
Office Software Thread, Disable screensaver whilst playing slideshows in Powerpoint 2010 in Technical; I've given a couple of teachers Office 2010 to play with and I've only had one complaint! The screensaver comes ...
  1. #1

    Ric_'s Avatar
    Join Date
    Jun 2005
    Location
    London
    Posts
    7,582
    Thank Post
    107
    Thanked 761 Times in 592 Posts
    Rep Power
    179

    Disable screensaver whilst playing slideshows in Powerpoint 2010

    I've given a couple of teachers Office 2010 to play with and I've only had one complaint! The screensaver comes on when they are playing powerpoint presentations.

    I thought there was a way to stop this happening within PowerPoint itself but it seems there is not - although every other aspect of the playing process can be changed!

    Ideas people?

    (btw - screensaver is controlled via GPO and I don't want to disable it completely)

  2. #2

    EduTech's Avatar
    Join Date
    Aug 2007
    Location
    Reading
    Posts
    4,979
    Thank Post
    158
    Thanked 888 Times in 699 Posts
    Blog Entries
    3
    Rep Power
    265

  3. #3

    Join Date
    Apr 2010
    Posts
    2
    Thank Post
    0
    Thanked 0 Times in 0 Posts
    Rep Power
    0

    Thumbs up Slideshow Stay Awake

    Download the attachment and rename it to *.vbs. I created a shortcut to this script on my desktop and named it "Slideshow Stay Awake". Simply drag-and-drop your presentation or slide show onto the shortcut, the script will do the rest. (It won't touch your screensaver or GPO settings at all.)

  4. #4

    Join Date
    Apr 2010
    Posts
    2
    Thank Post
    0
    Thanked 0 Times in 0 Posts
    Rep Power
    0
    Edugeek's attachment upload function seems to be broken. Here's the content of the attachment I tried to upload:

    '================================================= ==============================
    '
    ' Program : Slideshow.vbs
    ' Version : 1.0
    ' Created : 7-Apr-2010
    ' Author/s : Joe Bubbles
    '
    ' Purpose : Drag and drop a PowerPoint slideshow onto this program icon, it
    ' will then launch the slideshow and emulate a keystroke at
    ' predetermined intervals to avoid the screensaver activating, thus
    ' by-passing the screensaver password protection (if enabled).
    '
    '================================================= ==============================
    Option Explicit

    Const Keypress_Interval = 10 '(seconds)

    CheckHost
    KeepBusy Slideshow

    '_________________________________________________ ______________________________

    Function KeepBusy(Presentation)
    Dim objSHL, objEXE

    Const CommandLine = "cmd /C start ""Slideshow"" /realtime /wait "

    Set objSHL = CreateObject("WScript.Shell")
    Set objEXE = objSHL.Exec(CommandLine & """" & Presentation & """")

    DisplayHelp

    Do While objEXE.Status = 0 '(Still Running)
    objSHL.SendKeys "+" '(SHIFT, harmless during presentations)
    Wscript.Sleep Keypress_Interval * 1000
    Loop

    End Function 'KeepBusy
    '_________________________________________________ ______________________________

    Function Slideshow()
    Dim objArgs, t

    t = ""
    Set objArgs = WScript.Arguments

    If (objArgs.Count > 0) Then
    t = objArgs(0)
    Else
    WScript.Quit
    End If

    Slideshow = t

    End Function 'Slideshow
    '_________________________________________________ ______________________________

    Sub CheckHost()
    Dim objSHL

    Const Q = """"
    Set objSHL = CreateObject("Wscript.Shell")

    If Not WScript.FullName = WScript.Path & "\cscript.exe" Then
    objSHL.Run "cmd /c " & WScript.Path & "\cscript.exe //NOLOGO " & _
    Q & WScript.scriptFullName & Q & " " & Q & Slideshow & Q, _
    1, False
    WScript.Quit 0
    End If

    End Sub 'CheckHost
    '_________________________________________________ ______________________________

    Sub DisplayHelp()
    Dim t

    t = Slideshow
    t = Right(t, Len(t) - InStrRev(t, "\"))

    With WScript
    .Echo
    .Echo " This window will automatically close within " & _
    Keypress_Interval & " seconds "
    .Echo " after you close """ & t & """."
    .Echo
    End With 'WScript

    End Sub 'DisplayHelp
    '_________________________________________________ ______________________________

SHARE:
+ Post New Thread

Similar Threads

  1. Replies: 0
    Last Post: 20th August 2009, 07:07 PM
  2. [Video] For all you pratts who text whilst driving.....
    By mattx in forum Jokes/Interweb Things
    Replies: 12
    Last Post: 19th August 2009, 09:45 AM
  3. Powerpoint Slideshows
    By laserblazer in forum General Chat
    Replies: 4
    Last Post: 13th March 2009, 11:38 AM
  4. RockYou Style Photo SlideShows in PowerPoint
    By mattpant in forum Windows
    Replies: 6
    Last Post: 12th October 2006, 10:19 AM

Thread Information

Users Browsing this Thread

There are currently 1 users browsing this thread. (0 members and 1 guests)

Tags for this Thread

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •